# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
# Co-maintainer: Yurii Kolesnykov <root@yurikoles.com>
# Based on extra/electron* by
# Bruno Pagani <archange@archlinux.org>
# Caleb Maclennan <caleb@alerque.com>
_projectname=electron
_major=38
_pkgname="${_projectname}${_major}"
pkgname="${_pkgname}"-bin
_subver='8.6'
_pkgver="${_major}.${_subver}"
pkgver="${_pkgver/-/}"
pkgrel=1
pkgdesc="Build cross platform desktop apps with web technologies — prebuilt"
arch=(
  'aarch64'
  'armv7h'
  'x86_64'
)
url='https://electronjs.org'
_ghurl="https://github.com/electron/electron"
license=(
  'MIT'
  'LicenseRef-custom'
)
provides=(
  "${_pkgname}=${pkgver}"
)
conflicts=("${_pkgname}")
depends=(
  'alsa-lib'
  'gtk3'
  'nss'
)
optdepends=(
  'kde-cli-tools: file deletion support (kioclient5)'
  'pipewire: WebRTC desktop sharing under Wayland'
  'qt6-base: enable Qt6 with --enable-features=AllowQt'
  'gtk4: for --gtk-version=4 (GTK4 IME might work better on Wayland)'
  'trash-cli: file deletion support (trash-put)'
  "xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)"
)
noextract=(
  "${_pkgname}-chromedriver-${pkgver}-${CARCH}.zip"
  "${_pkgname}-${pkgver}-${CARCH}.zip"
)
source_aarch64=(
  "${_pkgname}-chromedriver-${pkgver}-aarch64.zip::${_ghurl}/releases/download/v${_pkgver//_/-}/chromedriver-v${_pkgver//_/-}-linux-arm64.zip"
  "${_pkgname}-${pkgver}-aarch64.zip::${_ghurl}/releases/download/v${_pkgver//_/-}/electron-v${_pkgver//_/-}-linux-arm64.zip"
)
source_armv7h=(
  "${_pkgname}-chromedriver-${pkgver}-armv7h.zip::${_ghurl}/releases/download/v${_pkgver//_/-}/chromedriver-v${_pkgver//_/-}-linux-armv7l.zip"
  "${_pkgname}-${pkgver}-armv7h.zip::${_ghurl}/releases/download/v${_pkgver//_/-}/electron-v${_pkgver//_/-}-linux-armv7l.zip"
)
source_x86_64=(
  "${_pkgname}-chromedriver-${pkgver}-x86_64.zip::${_ghurl}/releases/download/v${_pkgver//_/-}/chromedriver-v${_pkgver//_/-}-linux-x64.zip"
  "${_pkgname}-${pkgver}-x86_64.zip::${_ghurl}/releases/download/v${_pkgver//_/-}/electron-v${_pkgver//_/-}-linux-x64.zip"
)
sha256sums_aarch64=('c631ce6c3ae764cb78b366f79169f9c62438b28556d24ee7a3a8e4225a881f22'
  'add5aaa35ed57e60f84b780f6461064b912de55effd27ec11e338462243867a5')
sha256sums_armv7h=('5edf7665cd5a606d701fbdb8c6fc6edf0dbab635e9312448fa024e4fc51a6e54'
  'cfbe4376edccbd1b9cd75ebb1def48fb9e35a4d794835ac9b5712da7bbdcca43')
sha256sums_x86_64=('a46f76cb255b98a52f1a446cfb5497f5b87cc95ddd1ccbe77244607a37f2fed8'
  '41a8f2bc7c0be836b4dc8de19550a65947cffa58433753032af36ee3b849e8be')
prepare() {
  install -Dm755 -d "${srcdir}/${_pkgname}"
  bsdtar -xf "${srcdir}/${_pkgname}-${pkgver}-${CARCH}.zip" -C "${srcdir}/${_pkgname}"
  bsdtar -xf "${srcdir}/${_pkgname}-chromedriver-${pkgver}-${CARCH}.zip" -C "${srcdir}/${_pkgname}"
  rm -rf "${srcdir}/${_pkgname}/"{gen,chromedriver.debug}
  chmod u+s "${srcdir}/${_pkgname}/chrome-sandbox"
}
package() {
  install -Dm755 -d "${pkgdir}/usr/"{bin,lib}
  cp -r --no-preserve=ownership --preserve=mode "${srcdir}/${_pkgname}" "${pkgdir}/usr/lib"
  ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
  rm -rf "${pkgdir}/usr/lib/${_pkgname}/LICENSE"*
  install -Dm644 "${srcdir}/${_pkgname}/LICENSE"* -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
