# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
# Co-maintainer: Yurii Kolesnykov <root@yurikoles.com>
# Based on extra/electron* by
# Bruno Pagani <archange@archlinux.org>
# Caleb Maclennan <caleb@alerque.com>
_projectname=electron
_major=37
_pkgname="${_projectname}${_major}"
pkgname="${_pkgname}"-bin
_subver='10.3'
_pkgver="${_major}.${_subver}"
pkgver="${_pkgver}"
pkgrel=1
pkgdesc="Build cross platform desktop apps with web technologies — prebuilt"
arch=(
  'aarch64'
  'armv7h'
  'x86_64'
)
url='https://electronjs.org'
_ghurl="https://github.com/electron/electron"
license=(
  'MIT'
  'LicenseRef-custom'
)
provides=(
  "${_pkgname}=${pkgver}"
)
conflicts=("${_pkgname}")
depends=(
  'alsa-lib'
  'gtk3'
  'nss'
)
optdepends=(
  'kde-cli-tools: file deletion support (kioclient5)'
  'pipewire: WebRTC desktop sharing under Wayland'
  'qt6-base: enable Qt6 with --enable-features=AllowQt'
  'gtk4: for --gtk-version=4 (GTK4 IME might work better on Wayland)'
  'trash-cli: file deletion support (trash-put)'
  "xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)"
)
noextract=(
  "${_pkgname}-chromedriver-${pkgver}-${CARCH}.zip"
  "${_pkgname}-${pkgver}-${CARCH}.zip"
)
source_aarch64=(
  "${_pkgname}-chromedriver-${pkgver}-aarch64.zip::${_ghurl}/releases/download/v${_pkgver}/chromedriver-v${_pkgver}-linux-arm64.zip"
  "${_pkgname}-${pkgver}-aarch64.zip::${_ghurl}/releases/download/v${_pkgver}/electron-v${_pkgver}-linux-arm64.zip"
)
source_armv7h=(
  "${_pkgname}-chromedriver-${pkgver}-armv7h.zip::${_ghurl}/releases/download/v${_pkgver}/chromedriver-v${_pkgver}-linux-armv7l.zip"
  "${_pkgname}-${pkgver}-armv7h.zip::${_ghurl}/releases/download/v${_pkgver}/electron-v${_pkgver}-linux-armv7l.zip"
)
source_x86_64=(
  "${_pkgname}-chromedriver-${pkgver}-x86_64.zip::${_ghurl}/releases/download/v${_pkgver}/chromedriver-v${_pkgver}-linux-x64.zip"
  "${_pkgname}-${pkgver}-x86_64.zip::${_ghurl}/releases/download/v${_pkgver}/electron-v${_pkgver}-linux-x64.zip"
)
sha256sums_aarch64=('e7e4b0b21d8e685ef5ad32d8281025fc80cf4cb5bd9476642c26d702c8f3a59e'
  '37a228821184136fa86a8727bec19ab400524dd7d4bca78937de5d50704592d1')
sha256sums_armv7h=('f14f0122e94d6df6f04f682c4e14d1f21608b256b5c90c34c6567e3487b904dc'
  'db4c1f6c8f012ddd15965c5f8837a61b65d0c3f8f296d81e3f0bf7158ef9779f')
sha256sums_x86_64=('ced6d8721ce57a3fa10d2bc614e4d49ab031c46629ed5af03a253ce7def8b747'
  'c0b4edd6bd9858cda4cf7ab299e69a2d3ecd2e5fcca78507bc0851ba35614660')
prepare() {
  install -Dm755 -d "${srcdir}/${_pkgname}"
  bsdtar -xf "${srcdir}/${_pkgname}-${pkgver}-${CARCH}.zip" -C "${srcdir}/${_pkgname}"
  bsdtar -xf "${srcdir}/${_pkgname}-chromedriver-${pkgver}-${CARCH}.zip" -C "${srcdir}/${_pkgname}"
  rm -rf "${srcdir}/${_pkgname}/"{gen,chromedriver.debug}
  chmod u+s "${srcdir}/${_pkgname}/chrome-sandbox"
}
package() {
  install -Dm755 -d "${pkgdir}/usr/"{bin,lib}
  cp -r --no-preserve=ownership --preserve=mode "${srcdir}/${_pkgname}" "${pkgdir}/usr/lib"
  ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
  install -Dm644 "${srcdir}/${_pkgname}/LICENSE"* -t "${pkgdir}/usr/share/licenses/${pkgname}"
  rm -rf "${pkgdir}/usr/bin/${_pkgname}/LICENSE"*
}
