# Maintainer: aur.chaotic.cx

_pkgname="detect-it-easy"
pkgname="$_pkgname-git"
pkgver=3.21.r400.gab0ea3e
pkgrel=1
pkgdesc="Program to determine types of files"
url="https://github.com/horsicq/DIE-engine"
license=('MIT')
arch=('x86_64')

depends=(
  'hicolor-icon-theme'
  'qt6-5compat'
  'qt6-base'
  'qt6-declarative'
  'qt6-svg'
)
makedepends=(
  'cmake'
  'git'
  'ninja'
  'qt6-tools'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

options=('!docs' '!lto')

_pkgsrc="DIE-engine"
source=("$_pkgsrc"::"git+$url.git")
sha512sums=('SKIP')

prepare() {
  cd "$_pkgsrc"
  git submodule update --init --recursive --depth=1

  # prevent Qt5
  sed -E -e 's&Qt5&Qt6&' -i src/CMakeLists.txt
}

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z]*' \
    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -Wno-author

    -DDIE_QT_MAJOR=6
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "$_pkgsrc/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
