pkgname=basedpyright
pkgver=1.39.9
pkgrel=1
pkgdesc="pyright fork with various improvements and pylance features"
arch=("any")
url=https://docs.basedpyright.com/
license=("MIT")
depends=("nodejs")
makedepends=(pnpm
  uv
  # generateAllDocstubs
  python
  tk)
source=("$pkgname-$pkgver.tar.gz::https://github.com/DetachHead/basedpyright/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('7b5a8df1be0d5fad25aec7b0a6ee728fe5f1e4f70549906559dc0630191c049f')

prepare() {
  cd "$pkgname-$pkgver"
  # We let uv use system python here.
  rm -f .python-version
  # ./build/generateAllDocstubs.sh
  uv sync --only-group=docstubs --no-install-project
  uv run --no-sync build/py3_8/generate_docstubs.py
  pnpm install
}

build() {
  cd "$pkgname-$pkgver/packages/pyright"
  pnpm run build
}

package() {
  cd "$pkgname-$pkgver"
  local target="$pkgdir/usr/lib/node_modules/$pkgname"
  mkdir -p "$pkgdir/usr/bin" "$target"
  ln -s ../lib/node_modules/$pkgname/index.js "$pkgdir/usr/bin/$pkgname"
  ln -s ../lib/node_modules/$pkgname/langserver.index.js "$pkgdir/usr/bin/$pkgname-langserver"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"

  cd packages/pyright
  cp -r dist {,langserver.}index.js package.json "$target"
}
