# shellcheck disable=SC2148,SC2206,SC2034,SC2154
# Release-Online / Non-dev
# Maintainer: Hadean Eon <hadean-eon-dev@proton.me>
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Giancarlo Razzolini <grazzolini@archlinux.org>
# Contributor: Anton Hvornum <torxed@archlinux.org>

pkgname=archinstoo-git
pkgver=r5755.456bb384
pkgrel=1
pkgdesc="Archinstall revamped"
arch=(any)
url="https://github.com/h8d13/archinstoo"
license=(GPL-3.0-only)
depends=(
	'python-pyparted'
	'python'
	'arch-install-scripts' #For pacstrap, genfstab, chroot
	'systemd'              #For systemd-based operations
	'coreutils'            #Basic utilities
	'util-linux'           #For partition utilities
	'pciutils'             #For PCI device detection
	'kbd'                  #For keyboard layout configuration
	'libxcrypt'
	'pacman'
	'git'         #cloning stashes
	'btrfs-progs' #btrfs filesystem support
	'dosfstools'  #FAT EFI filesystem support
	'e2fsprogs'   #ext4 filesystem support
	'f2fs-tools'  #f2fs filesystem support
	'ntfsprogs'     #NTFS filesystem support
	'xfsprogs'    #XFS filesystem support
	'cryptsetup'  #LUKS encryption support
	'lvm2'        #LVM layout support
)
makedepends=(
	'python-build'
	'python-installer'
	'python-setuptools'
	'python-wheel'
)

provides=(archinstoo)
replaces=(archinstoo)
source=("$pkgname::git+$url.git")
sha512sums=('SKIP')

pkgver() {
	cd "$pkgname" || exit
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$pkgname/installer" || exit

	# wheel has no PKGBUILD to read at runtime: stamp the fallback
	sed -i "s/^__pkgstamp__ = '[^']*'/__pkgstamp__ = '$pkgver-$pkgrel'/" archinstoo/_version.py
	python -m build --wheel --no-isolation
}

package() {
	cd "$pkgname/installer" || exit

	python -m installer --destdir="$pkgdir" dist/*.whl
	install -vDm 644 docs/archinstoo.1 -t "$pkgdir/usr/share/man/man1/"
}
